ADO Speed Up With GetString()
Use the GetString() method to speed up your ASP script (instead
of using multiple Response.Write's).
Multiple Response.Write's
The following example demonstrates one way of how to display a
database query in an HTML table:
<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>
<table border="1" width="100%">
<%do until rs.EOF%>
<tr>
<td><%Response.Write(rs.fields("Companyname"))%></td>
<td><%Response.Write(rs.fields("Contactname"))%></td>
</tr>
<%rs.MoveNext
loop%>
</table>
<%
rs.close
conn.close
set rs = Nothing
set conn = Nothing
%>
</body>
</html>
|
For a large query, this can slow down the script processing time, since
many Response.Write commands must be processed by the server.
The solution is to have the entire string created, from <table> to </table>,
and
then output it - using Response.Write just once.
The GetString() Method
The GetString() method allows you to display the string with only one Response.Write.
It also eliminates the do...loop code and the conditional test that checks if
the recordset is at EOF.
Syntax
|
str = rs.GetString(format,rows,coldel,rowdel,nullexpr)
|
To create an HTML table with data from a recordset, we only need to use three of the parameters above
(all parameters are optional):
- coldel - the HTML to use as a column-separator
- rowdel - the HTML to use as a row-separator
- nullexpr - the HTML to use if a column is NULL
Note: The GetString() method is an ADO 2.0 feature. You can download ADO 2.0 at
http://www.microsoft.com/data/download.htm.
In the following example we will use the GetString() method to hold the
recordset as a string:
Example
<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
str=rs.GetString(,,"</td><td>","</td></tr><tr><td>"," ")
%>
<table border="1" width="100%">
<tr>
<td><%Response.Write(str)%></td>
</tr>
</table>
<%
rs.close
conn.close
set rs = Nothing
set conn = Nothing
%>
</body>
</html>
|
Show example »
|
The str variable above contains a string of all the columns and rows
returned by the SQL SELECT statement. Between each
column the HTML
</td><td> will appear, and between each row, the HTML </td></tr><tr><td> will
appear. This will produce the exact HTML we need with only one Response.Write.
Click here to design a Stunning Flash Website for Free
Wix is a revolutionary web design tool that provides anyone with the possibility to create professional and beautiful websites for free.
With e-commerce features, search engine visibility and many more professional tools, Wix is the ultimate solution for creating a spectacular site while saving tons of money.
 |
W3Schools' Online Certification Program
The perfect solution for professionals who need to balance work, family, and career building.
More than 4500 certificates already issued!
|
The HTML Certificate documents your knowledge of HTML, XHTML, and CSS.
The JavaScript Certificate documents your knowledge of JavaScript and HTML DOM.
The XML Certificate documents your knowledge of XML, XML DOM and XSLT.
The ASP Certificate documents your knowledge of ASP, SQL, and ADO.
The PHP Certificate documents your knowledge of PHP and SQL (MySQL).
| 
